[ASP] Question générale très simple

Question générale très simple [ASP] - ASP - Programmation

Marsh Posté le 15-02-2003 à 14:20:37    

je m'intéresse à ASP depuis peu mais avant de me lancer dedans j'aimerais être sur de bien comprendre :
 
c'est quoi le code ASP.net (et ASP normal) ?c du vbscript ou c du code spécifique ASP ?
 
voici comment je vois la chose et dites moi si je débloque ou si c juste :
 
je pense donc moi que le code qui est produit lorsqu'on programme avec ASP.NET est du vbscript.
pour qu'une application ASP fonctionne il faut qu'elle soit mise sur un serveur. ASP étant un produit de MS, il faut que le serveur utilise IIS sinon c'est mort.
si le serveur a IIS (et ASP), lorsqu'une personne télécharge une page asp que l'on a créée (.aspx l'extension ?), le serveur traduit le code vbscript de notre application qui est sur le serveur et le renvoit sous forme de bloque html et balises vbscript interprétable par le navigateur qui affiche les infos au user.
 
Je suis à coté de la plaque ? expliquez moi ça serait génial !
merci d'avance
 
Meilleurs progs
a+

Reply

Marsh Posté le 15-02-2003 à 14:20:37   

Reply

Marsh Posté le 12-03-2003 à 23:59:18    

En fait une page ASP contient un mélange de script et de HTML.  
Quand tu appelle une page ASP, "le serveur" va interpréter les instructions du script pour générer du code HTML, seul code compréhensible par un navigateur (on peut aussi générer ainsi du Javascript si on veut) qui va alors afficher le résultat.  
La différence entre ASP et ASP.NET c'est qu'en .NET, on sépare dans 2 fichiers distincts code et HTML. De plus, .NET permet le dvt objet, mais là ça se complique un peu...
 [:rem']


---------------
@ + : Rem'
Reply

Marsh Posté le 13-03-2003 à 00:15:15    

on peut écrire l'ASP en JavaScript aussi, mais c'est pas supporté par le SAV de M$

Reply

Marsh Posté le 13-03-2003 à 06:56:49    

Rem' a écrit :

De plus, .NET permet le dvt objet, mais là ça se complique un peu...
 [:rem']  


continue tu m'intéresse  :)


---------------
.: Clône de Drasche .:. Ebichuleys .:. Avec l'Aloe Vera je fais de beaux cacas [:dawa] .: www.oserselancer.com :.
Reply

Marsh Posté le 15-03-2003 à 00:41:14    

Comme je te l'ai dit tu peux développer objet en .Net mais autant trouver un bon tutorial, parce que la leçon serait longue. Grosso modo, chaquye éléement de ton formulaire est un objet identifié par un ID unique. Aussi tu peux accéder à chacun de ces éléments grâce à son ID, sans mélanger script et HTML...
[:rem']


---------------
@ + : Rem'
Reply

Marsh Posté le 15-03-2003 à 14:04:43    

Juste pour info, contrairement à ce que beaucoup de ges croient, VB et donc l'ASP tout cours, supporte les objets. C'est évidement pas aussi poussé que Java par exemple, mais cela permet de faire des choses pas mal déjà.
 
Exemple d'un objet programmé en ASP
 

Code :
  1. <%
  2. ' ------------------------------------------------------------------------------
  3. ' Container of Field Properties
  4. Class clsField
  5. Public FileName
  6. Public ContentType
  7. Public Value
  8. Public FieldName
  9. Public Length
  10. Public BinaryData
  11. End Class
  12. ' ------------------------------------------------------------------------------
  13. Class clsUpload
  14. ' ------------------------------------------------------------------------------
  15. Private nFieldCount
  16. Private oFields()
  18. ' ------------------------------------------------------------------------------
  19. Public Property Get Count()
  20.  Count = nFieldCount
  21. End Property
  22. ' ------------------------------------------------------------------------------
  23. Public Default Property Get Field(ByRef asFieldName)
  24.  Dim lnLength
  25.  Dim lnIndex
  27.  lnLength = UBound(oFields)
  29.  If IsNumeric(asFieldName) Then
  30.   If lnLength >= asFieldName And asFieldName > -1 Then
  31.    Set Field = oFields(asFieldName)
  32.   Else
  33.    Set Field = New clsField
  34.   End If
  35.  Else
  36.   For lnIndex = 0 To lnLength
  37.    If LCase(oFields(lnIndex).FieldName) = LCase(asFieldName) Then
  38.     Set Field = oFields(lnIndex)
  39.     Exit Property
  40.    End If
  41.   Next
  42.   Set Field = New clsField
  43.  End If
  44. End Property
  45. ' ------------------------------------------------------------------------------
  46. Public Function Exists(ByRef avKeyIndex)
  47.  Exists = Not IndexOf(avKeyIndex) = -1
  48. End Function
  49. ' ------------------------------------------------------------------------------
  50. Public Property Get ValueOf(ByRef avKeyIndex)
  51.  Dim lnIndex
  52.  lnIndex = IndexOf(avKeyIndex)
  53.  if lnIndex = -1 Then Exit Property
  54.  ValueOf = oFields(lnIndex).Value
  55. End Property
  56. ' ------------------------------------------------------------------------------
  57. Public Property Get FileNameOf(ByRef avKeyIndex)
  58.  Dim lnIndex
  59.  lnIndex = IndexOf(avKeyIndex)
  60.  if lnIndex = -1 Then Exit Property
  61.  FileNameOf = oFields(lnIndex).FileName
  62. End Property
  63. ' ------------------------------------------------------------------------------
  64. Public Property Get LengthOf(ByRef avKeyIndex)
  65.  Dim lnIndex
  66.  lnIndex = IndexOf(avKeyIndex)
  67.  if lnIndex = -1 Then Exit Property
  68.  LengthOf = oFields(lnIndex).LengthOf
  69. End Property
  70. ' ------------------------------------------------------------------------------
  71. Public Property Get BinaryDataOf(ByRef avKeyIndex)
  72.  Dim lnIndex
  73.  lnIndex = IndexOf(avKeyIndex)
  74.  if lnIndex = -1 Then Exit Property
  75.  BinaryDataOf = oFields(lnIndex).BinaryData
  76. End Property
  77. ' ------------------------------------------------------------------------------
  78. Private Function IndexOf(ByVal avKeyIndex)
  79.  Dim lnIndex
  80.  If IsNumeric(asFieldName) Then
  81.   avKeyIndex = CLng(avKeyIndex)
  82.   If nFieldCount > avKeyIndex And avKeyIndex > -1 Then
  83.    IndexOf = avKeyIndex
  84.   Else
  85.    IndexOf = -1
  86.   End If
  87.  Else
  88.   For lnIndex = 0 To nFieldCount - 1
  89.    If LCase(oFields(lnIndex).FieldName) = LCase(avKeyIndex) Then
  90.     IndexOf = lnIndex
  91.     Exit Function
  92.    End If
  93.   Next
  94.   IndexOf = -1
  95.  End If
  96. End Function
  97. ' ------------------------------------------------------------------------------
  98. Public Property Get ContentTypeOf(ByRef avKeyIndex)
  99.  Dim lnIndex
  100.  lnIndex = IndexOf(avKeyIndex)
  101.  if lnIndex = -1 Then Exit Property
  102.  ContentTypeOf = oFields(lnIndex).ContentType
  103. End Property
  104. ' ------------------------------------------------------------------------------
  105. Private Sub Class_Terminate()
  106.  For lnIndex = 0 To nFieldCount - 1
  107.   Set oFields(0) = Nothing
  108.  Next
  109. End Sub
  110. ' ------------------------------------------------------------------------------
  111. Private Sub Class_Initialize()
  113.  Dim lnBytes    ' Bytes received from the client
  114.  Dim lnByteCount   ' Number of bytes received
  115.  Dim lnStartPosition  ' Position at which content begins
  116.  Dim lnEndPosition  ' Position at which content ends
  118.  Dim loDic    ' Contains properties of each
  119.        ' specific field
  120.        ' Local dictionary object(s)
  121.        ' to be appended to class-scope
  122.        ' dictioary object.
  124.  Dim lnBoundaryBytes  ' Bytes contained within the current boundary
  125.  Dim lnBoundaryStart  ' Position at wich the current boundary begins
  126.        ' within the lnBytes binary data.
  127.  Dim lnBoundaryEnd  ' Position at wich the current boundary ends
  128.        ' within the lnBytes binary data.
  129.  Dim lnDispositionPosition
  131.  Dim lsFieldName   ' Name of the current field being parsed from
  132.        ' Binary Data
  133.  Dim lsFileName   ' Name of the file within the current boundary
  134.  Dim lnFileNamePosition ' Location of file name within current boundary
  136.  ' Initialize Fields
  137.  nFieldCount = 0
  138.  ReDim oFields(-1)
  140.  ' Read the bytes (binary data) into memory
  141.  lnByteCount = Request.TotalBytes
  142.  lnBytes = Request.BinaryRead(lnByteCount)
  144.  'Get the lnBoundaryBytes
  145.  lnStartPosition = 1
  146.  lnEndPosition = InstrB(lnStartPosition, lnBytes, CStrB(vbCr))
  148.  lnBoundaryBytes = MidB(lnBytes, lnStartPosition, lnEndPosition - lnStartPosition)
  150.  lnBoundaryStart = InstrB(1, lnBytes, lnBoundaryBytes)
  153.  ' Loop until the BoundaryBytes begin with "--"
  154.  Do Until (lnBoundaryStart = InstrB(lnBytes, lnBoundaryBytes & CStrB("--" )))
  156.   ' All data within this boundary is stored within a local dictionary
  157.   ' to be appended to the class-scope dictionary.
  159.   ReDim Preserve oFields(nFieldCount)
  160.   nFieldCount = nFieldCount + 1
  162.   Set loField = New clsField
  164.   lnDispositionPosition = InstrB(lnBoundaryStart, lnBytes, CStrB("Content-Disposition" ))
  166.   ' Get an object name
  167.   lnStartPosition = InstrB(lnDispositionPosition, lnBytes, CStrB("name=" )) + 6
  168.   lnEndPosition = InstrB(lnStartPosition, lnBytes, CStrB("""" ))
  169.   lsFieldName = CStrU(MidB(lnBytes, lnStartPosition, lnEndPosition - lnStartPosition))
  170.   loField.FieldName = lsFieldName
  172.   ' Get the location fo the file name.
  173.   lnFileNamePosition = InstrB(lnBoundaryStart, lnBytes, CStrB("filename=" ))
  174.   lnBoundaryEnd = InstrB(lnEndPosition, lnBytes, lnBoundaryBytes)
  176.   'Test if object is a file
  177.   If Not lnFileNamePosition = 0 And lnFileNamePosition < lnBoundaryEnd Then
  179.    ' Parse Filename
  180.    lnStartPosition = lnFileNamePosition + 10
  181.    lnEndPosition =  InstrB(lnStartPosition, lnBytes, CStrB("""" ))
  182.    lsFileName = CStrU(MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition))
  183.    loField.FileName = lsFileName
  185.    ' Parse Content-Type
  186.    lnStartPosition = InstrB(lnEndPosition,lnBytes,CStrB("Content-Type:" )) + 14
  187.    lnEndPosition = InstrB(lnStartPosition,lnBytes,CStrB(vbCr))
  188.    ContentType = CStrU(MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition))
  189.    loField.ContentType = ContentType
  191.    ' Parse Content
  192.    lnStartPosition = lnEndPosition + 4
  193.    lnEndPosition = InstrB(lnStartPosition,lnBytes,lnBoundaryBytes)-2
  194.    Value = MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition)
  195.    loField.BinaryData = Value & CStrB(vbNull)
  196.    loField.Length = LenB(Value)
  197.   Else
  199.    ' Parse Content
  200.    lnStartPosition = InstrB(lnDispositionPosition, lnBytes, CStrB(vbCr)) + 4
  201.    lnEndPosition = InstrB(lnStartPosition, lnBytes, lnBoundaryBytes) - 2
  202.    Value = CStrU(MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition))
  203.    loField.Value = Value
  204.    loField.Length = Len(Value)
  205.   End If
  207.   Set oFields(UBound(oFields)) = loField
  209.   'Loop to next object
  210.   lnBoundaryStart = InstrB(lnBoundaryStart + LenB(lnBoundaryBytes), lnBytes, lnBoundaryBytes)
  212.   Set loField = Nothing
  214.  Loop
  216. End Sub
  217. ' ------------------------------------------------------------------------------
  218. Private Function CStrU(ByRef psByteString)
  219.  Dim lnLength
  220.  Dim lnPosition
  221.  lnLength = LenB(psByteString)
  222.  For lnPosition = 1 To lnLength
  223.   CStrU = CStrU & Chr(AscB(MidB(psByteString, lnPosition, 1)))
  224.  Next
  225. End Function
  226. ' ------------------------------------------------------------------------------
  227. Private Function CStrB(ByRef psUnicodeString)
  228.  Dim lnLength
  229.  Dim lnPosition
  230.  lnLength = Len(psUnicodeString)
  231.  For lnPosition = 1 To lnLength
  232.   CStrB = CStrB & ChrB(AscB(Mid(psUnicodeString, lnPosition, 1)))
  233.  Next
  234. End Function
  235. ' ------------------------------------------------------------------------------
  236. End Class
  237. ' ------------------------------------------------------------------------------
  238. %>

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed