Bonjour/Bonsoir à tous  
 
Je viens vers vous car je bloque sur mon script batch  
 
Voici ce que j'aimerais faire :
 
Je voudrais comparer 2 ip , dans un premier temps le script lance un ip config et copie le résultat dans un fichier IP.txt
 
avec une boucle for je récupère la ligne IPV4 et la copie dans un fichier iprécupéré .txt et la copie dans une variable IP1
 
Ensuite dans une boucle infinie le script relance un ipconfig et copie dans le fichier IP.txt en écrasant ce qu'il contenait
 
Ensuite le script récupère la ligne IPV4 et la stock dans la variable IP2
 
Puis il compare IP1 et IP2 , si les valeurs sont différentes alors il copie la nouvelle IPV4 soit IP2 dans le fichier iprécupéré.txt sans écraser ce qu'il y avait avant  
Sinon il recommence au niveau du 2 eme ipconfig
 
Ma problématique ben c'est que ça ne marche pas    , le programme ne tourne pas en boucle  
 
Voici ce que j'ai tenté de faire  
 
 
ipconfig > C:\Users\Justbio\Documents\test.txt
for /f "tokens=* delims=" %%a in ('type C:\Users\Justbio\Documents\test.txt^| Find /i "Adresse IPv4"') do echo %%a >> C:\Users\Justbio\Documents\test2.txt
for /f "tokens=* delims=" %%a in ('type C:\Users\Justbio\Documents\test.txt^| Find /i "Adresse IPv4"') do set %%a=%ip1%
 
@echo off
:boucle
 
ipconfig > C:\Users\Justbio\Documents\test.txt
for /f "tokens=* delims=" %%a in ('type C:\Users\Justbio\Documents\test.txt^| Find /i "Adresse IPv4"') do set %%a=%ip2%  
 
 
 
if %ip1% <> %ip2% ;
do echo  ip2 >> C:\Users\Justbio\Documents\test2.txt ;
 
else ""
 
 
goto boucle

Ton if a l'air étrange. Fais un if /? en ligne de commande et regarde ce que ça dit.

J'ai fais quelques modif d'après ton infos  
 
Mais ça ne tourne toujours pas en boucle
 
@echo off
:init
ipconfig > C:\Users\Justbio\Documents\test.txt
for /f "tokens=* delims=" %%a in ('type C:\Users\Justbio\Documents\test.txt^| Find /i "Adresse IPv4"') do echo %%a >> C:\Users\Justbio\Documents\test2.txt
for /f "tokens=* delims=" %%b in ('type C:\Users\Justbio\Documents\test.txt^| Find /i "Adresse IPv4"') do set ip1=%%b
:boucle
set ip1=0  
set ip2=0
ipconfig > C:\Users\Justbio\Documents\test.txt
for /f "tokens=* delims=" %%c in ('type C:\Users\Justbio\Documents\test.txt^| Find /i "Adresse IPv4"') do set ip2=%%c  
if %ip1% NEQ %ip2%  %ip2% >> C:\Users\Justbio\Documents\test2.txt
if %ip1% == %ip2% goto boucle

Bon, j' ai pas tout pige dans ton histoire, mais un truc comme celui ci devrait coller.
 

@echo off 
REM On vide le fichier de log  
copy /Y NUL "iplog.txt" > NUL 
 
REM identificateur de la ligne, a adapter selon le langage 
set ip_string="Adresse IPv4" 
 
REM pour ecrire l'adresse au premier passage dans loop 
set ip_old="" 
 
:loop 
REM On recupere la premiere valeur avec Adresse IPv4 sur la ligne et on la colle dans ip 
for /f "usebackq tokens=2 delims=:" %%f in (`ipconfig ^| findstr /c:%ip_string%`) do ( 
    set ip=%%f 
    goto :next 
) 
:next 
REM pour virer l'espace initial 
set ip=%ip:~1% 
REM Note: c'est a adapter si on a plusieurs adaptateurs reseau avec des adresses ipv4  
REM pour ne parser que quand on a rencontre la ligne avec le bon adaptateur 
 
REM on compare et on ecrit si differentes, puis on memorise la nouvelle valeur 
if not %ip_old% == %ip% ( 
    echo %ip% >> "iplog.txt" 
    set ip_old=%ip% 
) 
 
REM delai variable avant de re-tester, ici 60 secondes 
REM Si timeout n' est pas dispo sur votre environnement, adapter avec un astuce (ping...)  
timeout /t 60 > NUL 
goto :loop

 
A+,

Merci beaucoup gilou ! ton script rempli exactement les conditions que je recherchais !
Mais j'avoue être un poil déçu de n'avoir pas pu réussir seul