Auth4openvpn pour openvpn

Auth4openvpn pour openvpn - VB/VBA/VBS - Programmation

Marsh Posté le 18-03-2013 à 13:47:52    

Salut à tous,
 
je viens à votre rencontre car j'ai un problème avec le plugin auth4openvpn.
Ce plugin sert à faire de l'authentification LDAP pour OpenVPN.
 
Mon problème, c'est que lorsque le plugin est appelé par openvpn lors de la connexion de l'utilisateur, j'ai une erreur dans l'observateur d’événement, tandis que si je lance le plugin via un cmd, pas de problème, l'observateur d’événement m'affiche une info avec le nom d'utilisateur.
 
Dans tous les cas l'authentification se fait bien.
 
Voici le détail de l'erreur :

Code :
  1. - <Event xmlns="http://schemas.microsoft.com/win/2004/08/events/event">
  2. - <System>
  3.   <Provider Name="WSH" />
  4.   <EventID Qualifiers="49152">1</EventID>
  5.   <Level>2</Level>
  6.   <Task>0</Task>
  7.   <Keywords>0x80000000000000</Keywords>
  8.   <TimeCreated SystemTime="2013-03-18T10:28:52.000000000Z" />
  9.   <EventRecordID>6977</EventRecordID>
  10.   <Channel>Application</Channel>
  11.   <Computer>srv2008R2Hyperv</Computer>
  12.   <Security />
  13.   </System>
  14. - <EventData>
  15.   <Data>Auth4OpenVPN: 424, Objet requis</Data>
  16.   </EventData>
  17.   </Event>


 
J'ai tenté de contacter le créateur du plugin mais j'ai pas eu de réponse.
 
Voici le code du plugin :  

Code :
  1. '.............................................................................
  2. '  Auth4OpenVPN.vbs
  3. '  Jose Ortega,
  4. '  (C)2007.
  5. '  http://amigo4life.googlepages.com/openvpn
  6. '
  7. '.............................................................................
  8. Option Explicit
  10. Const SEVERITY_INFO = &H00
  11. Const SEVERITY_ERROR = &H01
  12. Const SEVERITY_WARNING = &H02
  14. Const ADS_SECURE_AUTHENTICATION = &H01
  15. Const ADS_USE_ENCRYPTION = &H02
  16. Const ADS_SERVER_BIND = &H0200
  18. Const ADS_SCOPE_SUBTREE = &H02
  19. Const cfgFilePath = "auth4openvpn.ini"
  20. 'Const cfgFilePath = "c:\program files\openvpn\config\auth4openvpn.ini"
  22. Dim fileContent, parameters,ovUser, ovPass
  24. '.............................................................................
  26. sub LogEvent(EventDescription, EventType)
  27.         Dim objShell
  28. Set objShell = Wscript.CreateObject("Wscript.Shell" )
  29. objShell.LogEvent EventType, EventDescription
  30.         Set objShell = nothing
  31. end sub
  33. '.............................................................................
  35. Sub Prn(textToPrint)
  36.     wscript.echo textToPrint
  37. end sub
  39. '.............................................................................
  41. Function LogError (byVal ErrNumber)
  42.          if errnumber = 0 then
  43.             LogError = FALSE
  44.             exit function
  45.          end if
  46.          Select Case ErrNumber
  47.                 case -2147217911, -2147023570
  48.                      LogEvent "Auth4OpenVPN: Incorrect credentials." & _
  49.                               vbNewline & _
  50.                               "Username: " & Ucase(ovUser), SEVERITY_WARNING
  51.                 case -2147217865
  52.                      LogEvent "Auth4OpenVPN: Cannot find server" & _
  53.                               " or LDAP path supplied.", SEVERITY_ERROR
  54.                 case else
  55.                      LogEvent "Auth4OpenVPN: " & errnumber & ", " & _
  56.                               err.description, SEVERITY_ERROR
  57.          end Select
  58.          LogError = TRUE
  59. end Function
  61. '.............................................................................
  63. Function IsAuthOK()
  64. Dim adoConn, AdoCmd, rsUserDN, rsGroupDN, userDN, groupDN, adUser
  65. Dim userGroupsArray, group
  66. Dim oDSP, myDSP, root
  67. Dim server, domain, ldapPath, adGroup, logging
  68. server = parameters(0) : domain = parameters(1)
  69.         ldapPath = parameters(2) : adGroup = parameters(3)
  70.         logging = parameters(4)
  71.         '------------------------------------------------------------------------
  72.         'check credentials
  73.         Set myDSP = GetObject("LDAP:" )
  74.         On Error Resume Next
  75.         Set root = myDSP.OpenDSObject("LDAP://" & server & "/" & _
  76.                                        "RootDSE", domain & "\" & ovUser, _
  77.                                        ovPass, ADS_SERVER_BIND AND _
  78.                                        ADS_USE_ENCRYPTION)
  79.         if LogError(err.number) then
  80.            on error goto 0    'disable on error resume
  81.            IsAuthOK = FALSE
  82.            Exit Function
  83.         end if
  84.         Set root = nothing
  87.        '------------------------------------------------------------------------
  89. Set adoConn = CreateObject("ADODB.Connection" )
  90. Set adoCmd = CreateObject("ADODB.Command" )
  91. with adoConn
  92.  .Provider = "ADsDSOObject"
  93.  .Properties("User ID" ) = domain & "\" & ovUser
  94.  .Properties("Password" ) = ovPass
  95.  .Properties("Encrypt Password" ) = TRUE
  96.  .Properties("ADSI Flag" ) = &H01
  97.  .Properties("Timeout" ) = 10
  98.                 .Open "Active Directory Provider"
  99. end with
  101.     with adoCmd
  102.  Set .ActiveConnection = adoConn
  103.  .Properties("Page Size" ) = 10
  104.  .Properties("Cache Results" ) = FALSE
  105.  .Properties("Searchscope" ) =  ADS_SCOPE_SUBTREE
  106.  '----------------------------------------------------------------
  107.  .CommandText = "SELECT distinguishedName FROM 'LDAP://" & _
  108.                                server & "/" & ldapPath & "' " & _
  109.                                "WHERE objectClass='user' " & _
  110.                                "AND saMaccountName='" & ovUser & "'"
  111.                 on error resume next
  112.                 Set rsUserDN = .Execute
  113.                 if LogError(err.number) then
  114.                    on error goto 0    'disable on error resume
  115.                    adoConn.Close
  116.                    Set adoConn = nothing
  117.                    Set AdoCmd = nothing
  118.                    IsAuthOK = FALSE
  119.                    Exit Function
  120.                 end if
  122.                 if rsUserDn.EOF then
  123.                    IsAuthOK = FALSE
  124.                    LogEvent "Auth4OpenVPN: Cannot find user under LDAP path" & _
  125.                             " set in Auth4OpenVPN.ini file.", SEVERITY_ERROR
  126.                    adoConn.Close
  127.                    Set adoConn = nothing
  128.                    Set AdoCmd = nothing
  129.                    Exit Function
  130.                 end if
  131.                 userDN = rsUserDN.Fields(0)
  133.  '----------------------------------------------------------------
  134.  .CommandText = "SELECT distinguishedName " & _
  135.     "FROM 'LDAP://" & _
  136.                                         server & "/" & ldapPath & "' " & _
  137.     "WHERE objectClass='group' " & _
  138.     "AND name='" & adGroup & "'"
  139.  Set rsGroupDN = .Execute
  140.  if rsGroupDN.EOF then
  141.                    IsAuthOK = FALSE
  142.                    LogEvent "Auth4OpenVPN: Cannot find Group under LDAP path" & _
  143.                             " set in Auth4OpenVPN.ini file.", SEVERITY_ERROR
  144.                    adoConn.Close
  145.                    Set adoConn = nothing
  146.                    Set AdoCmd = nothing
  147.                    Exit Function
  148.                 end if
  149.  groupDN=rsGroupDN.fields(0)
  151.  .CommandText = "SELECT distinguishedName " & _
  152.     "FROM 'LDAP://" & _
  153.                                         server & "/" & ldapPath & "' " & _
  154.     "WHERE objectClass='group' " & _
  155.     "AND name='" & adGroup & "'" & _
  156.     "AND member='" & userDN & "'"
  157.  Set rsGroupDN = .Execute
  158.  if not rsGroupDN.EOF then
  159.                    if Ucase(logging) = "ON" then
  160.                       LogEvent "Auth4OpenVPN: " & _
  161.                                "Authentication successful." & vbNewline & _
  162.                                "Username: " & Ucase(ovUser), SEVERITY_INFO
  163.                    end if
  164.                    IsAuthOK = TRUE
  165.                    adoConn.Close
  166.                    Set adoConn = nothing
  167.                    Set AdoCmd = nothing
  168.                    Exit Function
  169.  end if
  171. End With
  172. '--------------------------------------------------------------------
  173.         IsAuthOK = FALSE
  174.         LogEvent "Auth4OpenVPN: User is not a member of the group: " & _
  175.                  Ucase(adGroup) & vbNewline & "Username: " & _
  176.                  Ucase(ovUser), SEVERITY_WARNING
  177.         Set adUser = nothing
  178.         Set oDSP = nothing
  179. end Function
  181. '.............................................................................
  183. Function IsSettingsFileOK()
  184.         Dim objFSO, openFile
  185. Set objFSO = CreateObject("Scripting.FileSystemObject" )
  186. If objFSO.FileExists(cfgFilePath) Then
  187.    On Error Resume Next
  188.         set openFile = objFSO.OpenTexTFile(cfgFilePath)
  189.         if err.number then
  190.            IsSettingsFileOK = FALSE
  191.               LogEvent "Auth4OpenVPN: Cannot read Auth4OpenVPN.ini file.", _
  192.                        SEVERITY_ERROR
  193.               On Error Goto 0  'disable On Error Resume
  194.               Set objFSO = nothing
  195.               Exit Function
  196.         end if
  197.    fileContent = openFile.ReadAll
  198.    openFile.Close
  199.         Else
  200.             IsSettingsFileOK = FALSE
  201.             LogEvent "Auth4OpenVPN: The Auth4OpenVPN.ini file is missing.", _
  202.                      SEVERITY_ERROR
  203.             Set objFSO = nothing
  204.             Exit Function
  205. End If
  206. Set objFSO = nothing
  207. IsSettingsFileOK = TRUE
  208. end Function
  210. '.............................................................................
  212. Function GetFirstMatch(PatternToMatch, StringToSearch)
  213.     Dim regEx, CurrentMatch, CurrentMatches
  214.     Set regEx = New RegExp
  215.     with regEx
  216.          .Pattern = PatternToMatch
  217.          .IgnoreCase = TRUE
  218.          .Global = TRUE
  219.          .MultiLine = TRUE
  220.          Set CurrentMatches = .Execute(StringToSearch)
  221.     end with
  222.     GetFirstMatch = ""
  223.     If CurrentMatches.Count >= 1 Then
  224.         Set CurrentMatch = CurrentMatches(0)
  225.         If CurrentMatch.SubMatches.Count >= 1 Then
  226.             GetFirstMatch = CurrentMatch.SubMatches (0)
  227.         End If
  228.     End If
  229.     Set regEx = Nothing
  230. End Function
  232. '.............................................................................
  234. Function AreSettingsOK()
  235.     Dim pattern
  236.     Dim i
  237.     parameters = Array ("SERVER", "DOMAIN", "DN", "GROUP", "LOGGING" )
  239.     For i = 0 to 4
  240.         pattern = ".*\r\n\s*" & parameters(i) & "\s*\=\s*\""(.*)\"""
  241.         parameters(i) = Trim(getFirstMatch(pattern, fileContent))
  242.         if Len(parameters(i)) = 0 then
  243.            AreSettingsOK = FALSE
  244.            LogEvent "Auth4OpenVPN: Missing settings in Auth4OpenVPN.ini" & _
  245.                     " file.", SEVERITY_ERROR
  246.            Exit Function
  247.         end if
  248.     Next
  249.     AreSettingsOK = TRUE
  250. End Function
  252. '.............................................................................
  254. Function AreCredentialsOK()
  255.          if Wscript.Arguments.Count = 0 then
  256.             'no cmd args, read OpenVPN supplied credentials
  257.             Dim myObj
  258.             Set myObj = Wscript.CreateObject("Wscript.Shell" )
  259.             ovUser = myObj.ExpandEnvironmentStrings("%username%" )
  260.             ovPass = myObj.ExpandEnvironmentStrings("%password%" )
  261.             Set myObj = nothing
  263.             if Len(ovUser)=0 or Len(ovPass)=0 then
  264.                AreCredentialsOK = FALSE
  265.                LogEvent "Auth4OpenVPN: Empty username or password " & _
  266.                         "are not allowed.", SEVERITY_ERROR
  267.                Exit Function
  268.             end if
  269.             AreCredentialsOK = TRUE
  270.             Exit Function
  271.          '-------------------------------------------------------------------
  272.          Elseif Wscript.Arguments.Count = 2 then
  273.             'cmd args present, read user and pass provided for testing.
  274.             ovUser = Trim(Wscript.Arguments(0))
  275.             OvPass = Trim(Wscript.Arguments(1))
  276.             if Len(ovUser)=0 or Len(ovPass)=0 then
  277.                AreCredentialsOK = FALSE
  278.                LogEvent "Auth4OpenVPN: Empty username or password " & _
  279.                         "are not allowed.", SEVERITY_ERROR
  280.                Exit Function
  281.             end if
  282.             AreCredentialsOK = TRUE
  283.             Exit Function
  284.          Else
  285.             LogEvent "Auth4OpenVPN: Invalid number of arguments.", _
  286.                      SEVERITY_ERROR
  287.             AreCredentialsOK = FALSE
  288.          End If
  289. End Function
  291. '.............................................................................
  293. Sub Main
  295.     If AreCredentialsOk then
  296.     if IsSettingsFileOK then
  297.     if AreSettingsOK then
  298.     if IsAuthOk then
  299.        if Wscript.Arguments.Count = 0 then
  300.           wscript.quit(0)
  301.        else
  302.           Prn "Authentication successful." & vbNewline
  303.           wscript.quit(0)
  304.        end if
  305.     end if
  306.     end if
  307.     end if
  308.     end if
  309.     if Wscript.Arguments.Count = 0 then
  310.        wscript.quit(1)
  311.     else
  312.        Prn "Authentication failed." & vbNewline & _
  313.            "Check the Application logs for details." & vbNewline
  314.        wscript.quit(1)
  315.     end if
  317. end sub
  319. '.............................................................................
  321. Main
  323. '.............................................................................


 
Merci à vous tous
 
PS : Si je me suis trompé de catégorie. Mea Culpa.

Reply

Marsh Posté le 18-03-2013 à 13:47:52   

Reply

Marsh Posté le 20-03-2013 à 09:37:10    

Y'a personne qui s'y connait dans ce domaine ?
 
edit le 20/03/2012 à 18h06
 
j'ai continué de chercher dans les logs d'openvpn, et là je suis tombé sur cette ligne d'erreur :
c:\Progra~1\openvpn\config\Auth4OpenVPN.vbs(122, 20) Erreur d'éxécution Microsoft VBScript: Objet requis: 'adoConn'
 
Si ça vous parle plus qu'à moi, n'hésitez pas à me dire quoi corriger sur mon serveur vpn  :jap:


Message édité par Maitre Jedi le 20-03-2013 à 18:13:16
Reply

Marsh Posté le 23-03-2013 à 17:20:04    

up

Reply

Marsh Posté le 24-03-2013 à 16:10:24    

met le chemin complet vers ton fichier de config

Reply

Marsh Posté le 24-03-2013 à 18:56:48    

avec l'un ou l'autre chemin, même erreur...  :cry:


Message édité par Maitre Jedi le 24-03-2013 à 18:57:10
Reply

Marsh Posté le 27-03-2013 à 18:15:03    

up

Reply

Marsh Posté le 27-03-2013 à 19:29:04    

 
              Tu peux ajouter une centaine d'up, il n'y aura pas plus de réponse vu le détail de l'erreur
              et la précision du 20 dernier :   il manque des objets, sans cela ne peut pas fontionner ‼
 

Reply

Marsh Posté le 08-04-2013 à 18:01:56    

coucou,
 
j'ai enfin 5 minutes pour revenir sur ce projet
 
J'ai bien compris qu'il manquait des objets mais c'est juste lorsque l'appel est effectué depuis openvpn. Si je lance ce script depuis une invite de commande en mettant en paramètre le nom d'utilisateur et le mot de passe, par exemple : auth4openvpn.vbs user motdepasse, ça fonctionne...
 
C'est plus ça mon problème. Connaissez vous un moyen de débugger ce genre de problème ?
 
Merci à tous

Reply

Marsh Posté le 10-04-2013 à 15:29:39    

Bon j'avance dans mon projet...
 
plusieurs semaines après avoir envoyé un mail à l'auteur, j'ai enfin reçu une réponse de sa part. Il se dit étonné et m'a donné quelques pistes à explorer...
 
Après quelques heures passées, il s'avère que le problème intervient après la sortie d'Openvpn 2.1.4. Le script fonctionne parfaitement avec OpenVPN 2.0.9.
J'ai poussé plus loin l'exploration et j'en suis venu à la conclusion suivante :
Avec la version 2.0.9, le paramètre script-security n'est pas reconnu, il faut l'enlever tandis qu'à partir de la version 2.1.4, le paramètre est obligatoire pour pouvoir lancer des scripts. Donc je pense que mon problème se situe içi. Maintenant comment modifier le script pour que celui-ci refonctionne complètement comme avant. Aucune idée !!
 
Sur ces grandes avancées, je me replonge dedans et la moindre de vos idées est la bienvenue...

Reply

Marsh Posté le 09-04-2014 à 21:45:20    

Bonjour
 
J'ai un prb un peu similaire en tentant de le monter sur un W2012 (openvpn 2.3.2 - client 3.0.0)
 
Message dans log Application de W2012 : Auth4OpenVPN: -2147221164, Classe non enregistrée
Ca fonctionne parfaitement en ligne de commande.
 
Avez-vous trouvé une solution a votre problème ?
 
Merci d'avance

Reply

Marsh Posté le 09-04-2014 à 21:45:20   

Reply

Marsh Posté le 18-03-2015 à 00:19:12    

Bonjour Maitre Jedi,
 
I noticed the same problem on my Windows 2008 server.  
 
Apparently when running Auth4OpenVPN.vbs some environment variables are not set. Here is a solution from someone else who created a wrapper script to set the variables and then calls the authentication script. It now works ok for me.
 
https://forums.openvpn.net/topic17787.html
 
Wrapper:
 

Code :
  1. set LOCALAPPDATA=C:\Users\%USERNAME%\AppData\Local
  2. set CommonProgramFiles=C:\Program Files\Common Files
  3. set CommonProgramFiles(x86)=C:\Program Files (x86)\Common Files
  4. set CommonProgramW6432=C:\Program Files\Common Files
  5. C:\Windows\System32\cscript.exe "C:\Program Files\OpenVPN\config\Auth4OpenVPN.vbs"
  6. exit %errorlevel%


 
Then set this as the script in your .ovpn file:
 

Code :
  1. script-security 3
  2. auth-user-pass-verify Auth4OpenVPN-64bitWrapper.cmd via-env


 
 
This solution is now also listed on the orginal author's website: https://sites.google.com/site/amigo4life2/openvpn

Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed