Comment exécuter ma macro Excel automatiquement ?

Comment exécuter ma macro Excel automatiquement ? - VB/VBA/VBS - Programmation

Marsh Posté le 23-12-2012 à 13:22:50    

Bonjour,
 
je ne sais pas si je poste au bon endroit même s'il me semble que oui. J'ai un planning pour le boulot au format .ics (apparemment, c'est iCalcreator qui le génère si j'en crois le site web qui me fournit mon planning) et avant de l'importer dans mon google calendar, j'ai besoin de le modifier pour avoir un résultat "propre" à l'affichage en supprimer certaines cellules (le début de ma macro avec les Do-Loop) et en supprimant certains morceaux de texte dans les cellules (la fin de ma macro avec "cells.replace" ).
 
N'y connaissant rien, j'ai donc bidouillé à l'aide de google une macro Excel que voici:
 

Code :
  1. Sub Edition()
  3. Do
  4.     If Cells.Find(What:="DTSTAMP" ) Is Nothing Then
  5.        Exit Do
  6.     Else
  7.        Cells.Find(What:="DTSTAMP" ).Activate
  8.        Selection.EntireRow.Delete
  9.     End If
  10. Loop
  12. Do
  13.     If Cells.Find(What:="UID" ) Is Nothing Then
  14.        Exit Do
  15.     Else
  16.        Cells.Find(What:="UID" ).Activate
  17.        Selection.EntireRow.Delete
  18.     End If
  19. Loop
  21. Do
  22.     If Cells.Find(What:="METHOD" ) Is Nothing Then
  23.        Exit Do
  24.     Else
  25.        Cells.Find(What:="METHOD" ).Activate
  26.        Selection.EntireRow.Delete
  27.     End If
  28. Loop
  30. Do
  31.     If Cells.Find(What:="X-WR" ) Is Nothing Then
  32.        Exit Do
  33.     Else
  34.        Cells.Find(What:="X-WR" ).Activate
  35.        Selection.EntireRow.Delete
  36.     End If
  37. Loop
  39. Do
  40.     If Cells.Find(What:="LOCATION" ) Is Nothing Then
  41.        Exit Do
  42.     Else
  43.        Cells.Find(What:="LOCATION" ).Activate
  44.        Selection.EntireRow.Delete
  45.     End If
  46. Loop
  48. Do
  49.     If Cells.Find(What:="PRODID" ) Is Nothing Then
  50.        Exit Do
  51.     Else
  52.        Cells.Find(What:="PRODID" ).Activate
  53.        Selection.EntireRow.Delete
  54.     End If
  55. Loop
  57. Do
  58.     If Cells.Find(What:="VERSION" ) Is Nothing Then
  59.        Exit Do
  60.     Else
  61.        Cells.Find(What:="VERSION" ).Activate
  62.        Selection.EntireRow.Delete
  63.     End If
  64. Loop
  66. Dim feuil As Worksheet
  67. For Each feuil In ThisWorkbook.Worksheets
  68.     feuil.Cells.Replace What:="T080000", Replacement:=""
  69.     feuil.Cells.Replace What:="T180000", Replacement:=""
  70.     feuil.Cells.Replace What:="T010000", Replacement:=""
  71.     feuil.Cells.Replace What:="T100000", Replacement:=""
  72. Next feuil
  73. End Sub


 
Donc, j'ouvre mon planning dans Excel, je crée une nouvelle macro, je copie/colle ce texte, je lance la macro. Hourra, ça fonctionne et fait exactement ce que je veux.
 
Maintenant, j'aimerais éliminer "je crée une nouvelle macro, je copie/colle ce texte, je lance la macro". Je voudrais un truc transparent pour l'utilisateur au final "en un clic" (ou deux). Donc je sauvegarde ma macro au format .xlam. Je lance le fichier et j'y mets mon planning puis je lance la macro mais ... marche pas !
 
Je ne sais pas si je suis bien clair, mais mes connaissances en dessous de zéro en macro, vba, excel et autres font que j'ai du mal à exprimer autrement ...
 
Si quelqu'un a pigé ce que je veux faire et peut m'aider, merci beaucoup !!
 
(ou alors un logiciel tout fait qui me modifie mes plannings au format iCal directement !)


Message édité par dwarfy le 23-12-2012 à 13:29:10
Reply

Marsh Posté le 23-12-2012 à 13:22:50   

Reply

Marsh Posté le 26-12-2012 à 14:17:40    

 
              Bonjour !   J'en déduis que c'est une version supérieure à 2003 ...
 
              Cela ne marche pas, oui mais quoi et où ?   A suivre en mode pas à pas par exemple …
 
              Vis à vis du code exposé, si la procédure est enregistrée dans un fichier indépendant en  .xlam,
              en ligne 67 est utilisé ThisWorkbook faisant référence au fichier contenant la procédure,
              ne pouvant donc pas fonctionner sur un fichier planning externe ‼   Mieux vaut utiliser la propriété ActiveWorkbook …
 
              Autre chose, si une procédure comporte des répétitions dans lesquelles ne change qu'un paramètre,
              c'est préférable d'utiliser une boucle en y passant le paramètre afin d'alléger le code.
 
              Eviter absolument les .Activate & .Select pouvant énormément ralentir le processus;
              travailler directement sur les objets est bien plus concis et rapide !
 
              Dernier point :  lorsqu'il y a de nombreuses modifications dans un classeur,
                                     désactiver la mise à jour de l'écran (ScreenUpdating) rend l'exécution plus véloce …
 
              La procédure peut alors se "résumer" ainsi :
 

Code :
  1. Sub Edition()
  2.     Application.ScreenUpdating = False
  4.     For Each W In Split("DTSTAMP UID METHOD X-WR LOCATION PRODID VERSION" )
  5.         Do
  6.             Set Rg = Cells.Find(W)
  7.                  B = Rg Is Nothing
  8.             If Not B Then Rg.EntireRow.Delete
  9.         Loop Until B
  10.     Next
  12.     For Each Feuil In ActiveWorkbook.Worksheets
  13.         For Each W In Split("T080000 T180000 T010000 T100000" )
  14.             Feuil.Cells.Replace W, ""
  15.         Next W
  16.     Next Feuil
  18.     Application.ScreenUpdating = True
  19. End Sub


               J'ai préféré Split au lieu d'Array pour renvoyer un tableau …
 
               Pour continuer plus en avant, écrire un scénario en langage courant (& clair !) est nécessaire,
               cela fait ensuite gagner du temps et évite l'usine à gaz !
 
               Pour lancer automatiquement une macro à l'ouverture d'un classeur Excel, voir l'évènement Workbook_Open
               devant être codé dans le module ThisWorkbook et non pas dans un quelconque module standard …
 
               Pour afficher une boîte de dialogue afin de sélectionner un fichier, voir la méthode GetOpenFilename.
               Ouvrir ensuite le fichier via la méthode Workbooks.Open …


Message édité par Marc L le 26-12-2012 à 16:17:54
Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed