excel VBA : gestion des ";" lors d'un saveAS texte(DOS)

Marsh Posté le 01-07-2007 à 21:39:45

Bonjour,

J'écris des fichiers de programmation en VBA sous excel et j'essaye d'enregistrer le texte suivant :

montexte;

qui est écrit dans une ligne d'excel, au format texte(DOS) ;
et dans le fichier texte résultat je n'obtiens pas : montexte; MAIS : "montexte;"

Le problème vient du point-virgule puisque quand je l'enlève je n'ai plus les guillemets.

Savez-vous comment gérer ça ? c'est-à-dire comment enregistrer dans ce format texte(DOS), avec un point-virgule, et sans avoir des guillemets qui viennent s'imposer sans qu'on les demande ?

merci

Marsh Posté le 01-07-2007 à 21:39:45

Marsh Posté le 02-07-2007 à 13:44:47

tu enregistres ton montexte; dans quoi stp ?
explicites un peu le pb stp...

Marsh Posté le 02-07-2007 à 15:20:27

Option Explicit

Sub EnregistrementTexte()
Dim Chaine As String
Dim i As Long, j As Long
Dim NumFichier As Integer
Dim LastRow As Long, LastCol As Integer
Dim Separateur As String * 1

Separateur = ";"
NumFichier = FreeFile
LastRow = ShTest.Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
Open ThisWorkbook.Path & "\test.txt" For Output As #NumFichier
For i = 1 To LastRow
LastCol = ShTest.Range("IV" & i).End(xlToLeft).Column
Chaine = ""
For j = 1 To LastCol
If j = 1 Then
Chaine = ShTest.Cells(i, j)
Else
Chaine = Chaine & Separateur & ShTest.Cells(i, j)
End If
Next j
Print #NumFichier, Chaine
Next i
Close #NumFichier
End Sub

Message édité par kiki29 le 02-07-2007 à 19:37:33

Marsh Posté le 03-07-2007 à 13:40:57

ok,
merci kiki29, ça tourne.

j'avais fini par faire :

ActiveWorkbook.SaveAs Filename:= "\file.txt", FileFormat:= xlTextPrinter, CreateBackup:=False

je sais pas quelle est la meilleure solution; la plus courte ?

en tout cas problème résolu.

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed

Name *

Email *

URL

Message *