XML/XSLT : Transformer Balises et Attributs

Marsh Posté le 09-05-2013 à 02:00:32

Salut à tous,

Je suis débutante en XML/XSLT, j'ai lu les cours en ligne que j'ai pu trouver mais je galère à transformer mes balises et attributs. Rien n'est jamais parfait. Concrètement, j'aimerais faire un XSLT qui transformerait

<Titre Attribut="aaaa">
<Balise1 Att1="xxx" Att2="yyy">
<Balise2>
<Balise3>Machin</Balise3>
<Balise4>Bidule</Balise4>
</Balise2>
</Balise1>
</Titre>

en

<MonTitre MonAttribut="aaaa">
<MaBalise1 MonAtt1="xxx" MonAtt2="yyy">
<MaBalise2>
<MaBalise3>Machin</MaBalise3>
<MaBalise4>Bidule</MaBalise4>
</MaBalise2>
</MaBalise1>
</MonTitre>

Merci d'avance et désolée de mes questions qui sont sûrement idiotes à votre niveau !

Reply

Marsh Posté le 09-05-2013 à 02:00:32

Reply

Marsh Posté le 09-05-2013 à 03:03:11

A l'indentation près, ceci devrait coller:

Code :

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 
 
    <xsl:template match="node()|@*"> 
        <xsl:copy> 
          <xsl:apply-templates select="node()|@*"/> 
        </xsl:copy> 
    </xsl:template> 
 
    <xsl:template match="Titre"> 
      <MonTitre><xsl:apply-templates select="node()|@*"/></MonTitre> 
    </xsl:template> 
 
    <xsl:template match="Balise1"> 
      <MaBalise1><xsl:apply-templates select="node()|@*"/></MaBalise1> 
    </xsl:template> 
 
    <xsl:template match="Balise2"> 
        <MaBalise2><xsl:apply-templates select="node()|@*"/></MaBalise2> 
    </xsl:template> 
 
    <xsl:template match="Balise3"> 
      <MaBalise3><xsl:apply-templates select="node()|@*"/></MaBalise3> 
    </xsl:template> 
 
    <xsl:template match="Balise4"> 
        <MaBalise4><xsl:apply-templates select="node()|@*"/></MaBalise4> 
    </xsl:template> 
 
    <xsl:template match="@Attribut"> 
      <xsl:attribute name="MonAttribut"> 
        <xsl:value-of select="."/> 
      </xsl:attribute> 
    </xsl:template> 
 
    <xsl:template match="@Att1"> 
      <xsl:attribute name="MonAtt1"> 
        <xsl:value-of select="."/> 
      </xsl:attribute> 
    </xsl:template> 
 
    <xsl:template match="@Att2"> 
      <xsl:attribute name="MonAtt2"> 
        <xsl:value-of select="."/> 
      </xsl:attribute> 
    </xsl:template> 
 
</xsl:stylesheet>

A+,

Message édité par gilou le 09-05-2013 à 03:03:51

---------------
There's more than what can be linked! -- Iyashikei Anime Forever! -- AngularJS c'est un framework d'engulé! --

Reply

XML/XSLT : Transformer Balises et Attributs

Sujets relatifs:

Leave a Replay