XSLT

XSLT - XML/XSL - Programmation

Marsh Posté le 18-06-2012 à 01:28:19    

Bonsoir tout le monde,
 
Donc voila je coince depuis un moment pour transformer mon fichier xml en html.
Le problème c'est j'arrive pas à mettre les titres et prix des livres pour chaque éditeurs,  
voici mon code xml :

Code :
  1. <?xml version="1.0" encoding="utf-8" ?>
  2. <livres>
  4. <livre isbn="2841771482" annee="2002">
  5. <titre>Comprendre XSLT</titre>
  6. <auteur>Bernd Amann</auteur>
  7. <auteur>Philippe Rigaux</auteur>
  8. <resume>les webmastres d’aujourd’hui cherche</resume>
  9. </livre>
  11. <livre isbn="2841772373" annee="2003">
  12. <titre>Pratique de MYSQL et PHP</titre>
  13. <auteur>Philippe Rigaux </auteur>
  14. </livre>
  16. <livre isbn="2841779754" annee="1988">
  17. <titre>Savoir Programmer</titre>
  18. <auteur>Marc Lemaire</auteur>
  19. <auteur>Laurence Cesarini</auteur>
  20. <auteur>Dan Vodislav</auteur>
  21. <resume>Programmation pour les nuls</resume>
  22. </livre>
  24. <livre isbn="2456652271" annee="1994">
  25. <titre>Base de donnée Mysql/Oracle</titre>
  26. <auteur>Brahim Derdouri</auteur>
  27. <auteur>Mohammed Naîmi</auteur>
  28. </livre>
  30. <livre isbn="2456652401" annee="2004">
  31. <titre>Architecture des Ordinateurs</titre>
  32. <auteur>Bennoît Miramond</auteur>
  33. </livre>
  35. <livre isbn="2456651054" annee="2009">
  36. <titre>Logique et Programmation Logique</titre>
  37. <auteur>Yannick Kergosien</auteur>
  38. <auteur>Hans Rugh</auteur>
  39. <auteur>Christian Daveau</auteur>
  40. <auteur>Laura Hernandez</auteur>
  41. </livre>
  43. <livre isbn="2456659083" annee="2000">
  44. <titre>Developpement Web</titre>
  45. <auteur>Sebastien Chavanel</auteur>
  46. <auteur>Programmation Systeme</auteur>
  47. </livre>
  49. <livre isbn="2456651121" annee="2012">
  50. <titre>Réseau et Déploiment</titre>
  51. <auteur>Dntt</auteur>
  52. </livre>
  55. <editeur nom="0'Reilly">
  56. <isbn prix="18">2841772373</isbn>
  57. <isbn prix="33">2841771482</isbn>
  58. <isbn prix="14">2841779754</isbn>
  59. </editeur>
  61. <editeur nom="Dunod">
  62. <isbn prix="18">2456652271</isbn>
  63. <isbn prix="53">2456652401</isbn>
  64. <isbn prix="13">2456651054</isbn>
  65. <isbn prix="23">2456659083</isbn>
  66. <isbn prix="10">2456651121</isbn>
  67. </editeur>
  69. </livres>

 
 

Code :
  1. <?xml version="1.0" encoding="ISO-8859-1"?>
  2. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  3. <xsl:template match="/">
  4.   <html>
  5.     <head>
  6.       <title>Exemple de sortie HTML</title>
  7.       <meta http-equiv="Content-Type" content="text/html; charset=ISO-8859-1" />
  8.     </head>
  9.     <body>
  10. <xsl:for-each select="//editeur">  
  11.    <b>
  12.    <xsl:value-of select="@nom" /> (
  13.    <xsl:value-of select="count(isbn)" /> Livres)
  14. <br/>
  15.   </b>
  16. <ol><xsl:for-each select="//livre">
  17.  <li><xsl:if test="@isbn = //editeur/isbn">
  18.      <i><xsl:value-of select="titre" /></i>
  19.   (<xsl:value-of select="@annee" /> )
  20.   <xsl:value-of select="//editeur/isbn/@prix" /> euros,
  21.  nombre d'auteurs : <xsl:value-of select="count(auteur)" />
  23.  </xsl:if>
  24.  </li>
  25.       </xsl:for-each>
  26. </ol>
  27. </xsl:for-each>
  28. </body>
  29.   </html>
  30. </xsl:template>
  31. </xsl:stylesheet>

 
 
et voila le résultat en html :
 
0'Reilly ( 3 Livres)
 
 1.Comprendre XSLT (2002) 18 euros, nombre d'auteurs : 2
 2.Pratique de MYSQL et PHP (2003) 18 euros, nombre d'auteurs : 1
 3.Savoir Programmer (1988) 18 euros, nombre d'auteurs : 3
 4.Base de donnée Mysql/Oracle (1994) 18 euros, nombre d'auteurs : 2
 5.Architecture des Ordinateurs (2004) 18 euros, nombre d'auteurs : 1
 6.Logique et Programmation Logique (2009) 18 euros, nombre d'auteurs : 4
 7.Developpement Web (2000) 18 euros, nombre d'auteurs : 2
 8.Réseau et Déploiment (2012) 18 euros, nombre d'auteurs : 1
 
Dunod ( 5 Livres)
 
 1. Comprendre XSLT (2002) 18 euros, nombre d'auteurs : 2
 2.Pratique de MYSQL et PHP (2003) 18 euros, nombre d'auteurs : 1
 3.Savoir Programmer (1988) 18 euros, nombre d'auteurs : 3
 4.Base de donnée Mysql/Oracle (1994) 18 euros, nombre d'auteurs : 2
 5.Architecture des Ordinateurs (2004) 18 euros, nombre d'auteurs : 1
 6.Logique et Programmation Logique (2009) 18 euros, nombre d'auteurs : 4
 7.Developpement Web (2000) 18 euros, nombre d'auteurs : 2
 8.Réseau et Déploiment (2012) 18 euros, nombre d'auteurs : 1
 
alors que le résultat devrait ressembler a ceci :
 
0'Reilly ( 3 Livres)
 
 1.Comprendre XSLT (2002) 18 euros, nombre d'auteurs : 2
 2.Pratique de MYSQL et PHP (2003) 33 euros, nombre d'auteurs : 1
 3.Savoir Programmer (1988) 14 euros, nombre d'auteurs : 3
 
 
Dunod ( 5 Livres)
 
 
 1.Base de donnée Mysql/Oracle (1994) 18 euros, nombre d'auteurs : 2
 2.Architecture des Ordinateurs (2004) 53 euros, nombre d'auteurs : 1
 3.Logique et Programmation Logique (2009) 13 euros, nombre d'auteurs : 4
 4.Developpement Web (2000) 23 euros, nombre d'auteurs : 2
 5.Réseau et Déploiment (2012) 10 euros, nombre d'auteurs : 1
 
S'il vous plait aidez moi  
MERCI

Reply

Marsh Posté le 18-06-2012 à 01:28:19   

Reply

Marsh Posté le 18-06-2012 à 03:13:12    

En modifiant le moins possible ton code:

Code :
  1. <?xml version="1.0" encoding="ISO-8859-1"?> 
  2. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
  3.  
  4.   <xsl:key name="ISBN" match="livre" use="@isbn"/>  
  5.  
  6.   <xsl:template match="/"> 
  7.     <html> 
  8.       <head> 
  9.     <title>Exemple de sortie HTML</title> 
  10.     <meta http-equiv="Content-Type" content="text/html; charset=ISO-8859-1" /> 
  11.       </head> 
  12.       <body> 
  13.     <xsl:for-each select="//editeur">   
  14.       <b> 
  15.         <xsl:value-of select="@nom" /> ( 
  16.         <xsl:value-of select="count(isbn)" /> Livres) 
  17.         <br/> 
  18.       </b> 
  19.       <ol><xsl:for-each select="isbn"> 
  20.         <xsl:call-template name="livre"> 
  21.         <xsl:with-param name="PRIX" select="@prix"/> 
  22.         <xsl:with-param name="LIVRE" select="key('ISBN', text())"/> 
  23.         </xsl:call-template> 
  24.       </xsl:for-each> 
  25.       </ol> 
  26.     </xsl:for-each> 
  27.       </body> 
  28.     </html> 
  29.   </xsl:template> 
  30.  
  31.   <xsl:template name="livre"> 
  32.     <xsl:param name="PRIX"/>   
  33.     <xsl:param name="LIVRE"/>  
  34.     <li><i><xsl:value-of select="$LIVRE/titre" /></i> 
  35.     (<xsl:value-of select="$LIVRE/@annee" /> ) 
  36.     <xsl:value-of select="$PRIX" /> euros, 
  37.     nombre d'auteurs : <xsl:value-of select="count($LIVRE/auteur)" /></li>  
  38.   </xsl:template> 
  39.  
  40. </xsl:stylesheet>


Testé avec Saxon, et ça donne la sortie que tu désires.  
J'ai écrit ça vite fait, il y a peut être plus élégant.
A+,


Message édité par gilou le 18-06-2012 à 03:18:43

---------------
There's more than what can be linked! --  Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻
Reply

Marsh Posté le 18-06-2012 à 11:31:19    

Bon, maintenant que je suis réveillé, quelques commentaires:
 
<xsl:key name="ISBN" match="livre" use="@isbn"/>  
ça crée une sorte d'associative array, avec pour clé, la valeur de l'expression use dans le contexte du match, et comme valeur, une node list qui contiendra le match (et d'autres si on en rencontre plus tard avec la même valeur de clé).
 
<xsl:template name="livre">
    <xsl:param name="PRIX"/>  
    <xsl:param name="LIVRE"/>  
    ...
</xsl:template>
c'est comme une déclaration de fonction livre(PRIX, LIVRE) ou PRIX et LIVRE sont les deux parametres.
Dans le corps de la fonction, les paramètres sont représentés précédés d'un $: $LIVRE, $PRIX
 
<xsl:call-template name="livre">
        <xsl:with-param name="PRIX" select="@prix"/>
        <xsl:with-param name="LIVRE" select="key('ISBN', text())"/>
</xsl:call-template>
c'est comme l'appel de la fonction livre(@prix, key('ISBN', text()), ou la valeur des paramètres passés à l'appel est évaluée dans le contexte de l'appel.
 
Au vu de ton fichier xml, il était clair qu'on pouvait indexer les livres par leur valeur d'isbn, d'ou la déclaration de l'element xsl:key.
 
<xsl:for-each select="//editeur">  
  ...
  <xsl:for-each select="isbn">
  ...
  </xsl:for-each>
</xsl:for-each>
permet de traiter les livres pour chaque éditeur.
 
On est obligé de passer par un template nommé, car il faut des infos venant de deux contextes différents, celui des livres, et celui de l'éditeur, pour le prix.
Si on n'avait pas besoin du prix, un template normal de traitement des livres aurait suffi, <xsl:template match="livre">... avec un appel <xsl:apply-template select="key('ISBN', text())"/> à la place du template nommé.
 
 
A+,


Message édité par gilou le 18-06-2012 à 11:32:21

---------------
There's more than what can be linked! --  Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻
Reply

Marsh Posté le 18-06-2012 à 11:59:19    

Y'aurait peut-être à revoir la structure du xml pour avoir toutes les infos nécessaires sous la balise <livre> pour que ça soit plus simple à traiter :/

Message cité 1 fois

---------------
Astres, outil de help-desk GPL : http://sourceforge.net/projects/astres, ICARE, gestion de conf : http://sourceforge.net/projects/icare, Outil Planeta Calandreta : https://framalibre.org/content/planeta-calandreta
Reply

Marsh Posté le 18-06-2012 à 12:10:15    

Bonjour ,
 
Merci guilou pour ta réponse si rapide et si explicite .

Reply

Marsh Posté le 18-06-2012 à 12:13:47    

rufo a écrit :

Y'aurait peut-être à revoir la structure du xml pour avoir toutes les infos nécessaires sous la balise <livre> pour que ça soit plus simple à traiter :/

Parfois on n'a pas la maîtrise de ce genre de choses. Et c'est justement pour cela qu'il y a le xslt.
A+,


---------------
There's more than what can be linked! --  Le capitaine qui ne veut pas obéir à la carte finira par obéir aux récifs. -- No jab ? No job ! -- (╯°□°)╯︵ ┻━┻
Reply

Marsh Posté le 18-06-2012 à 12:48:55    

tout à fait, mais il n'a pas indiqué qu'il n'avait pas la maîtrise du xml...


---------------
Astres, outil de help-desk GPL : http://sourceforge.net/projects/astres, ICARE, gestion de conf : http://sourceforge.net/projects/icare, Outil Planeta Calandreta : https://framalibre.org/content/planeta-calandreta
Reply

Sujets relatifs:

Leave a Replay

Make sure you enter the(*)required information where indicate.HTML code is not allowed