Salut,
 
Je veux utiliser un compte fraichement créé dans le groupe admin des stations de travail (XP Pro, AD 2003).
 
Est-il possible de le faire par l'AD ? Une GPO ?
Je ne me souviens pas avoir vu cette possibilité par le passé.
 

les restricted group peuvent répondre à ça mais si tu n'a pas déjà des comptes inscrits "à la main" dans le groupe admin local

Malheureusement si, sur une partie il y'a l'utilisateur dans le groupe admin (oui, je sais... je verrai le prq du comment plus tard ).

Il y a celui fraichement créer ou un autre qui n'a rien à voir ?

Celui fraichement créé est juste pour se loguer sur les machines et faire les modifs (en tant qu'admin local).
 
C'est un autre qui n'a rien à voir, ~50 postes dont chaque user est admin de sa propre machine.

ok donc mauvaise idée

Une autre idée ?

essaye avec la commande 'net group' ou 'net user'

script vbs en démarrage de machine  
 
strComputer = "atl-ws-01"
strGroup = "Administrators"
strUser = "kenmyer"
Set objGroup = GetObject("WinNT://" & strComputer & "/" & strGroup & ",group" )
Set objUser = GetObject("WinNT://" & strComputer & "/" & strUser & ",user" )
objGroup.Add(objUser.ADsPath)
 
http://www.microsoft.com/technet/s [...] x?mfr=true
 
La touche perso pour le nom de machine :
 
Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName
 
Après tu peux en profiter pour ajouter une boucle qui audite les membres actuels histoire de valider la sécu! :
 
Set objNetwork = CreateObject("WScript.Network" )
strComputer = objNetwork.ComputerName
strGroup = "Administrators"
WScript.Echo "Computer: " & strComputer
Set objGroup = GetObject("WinNT://" & strComputer & "/" & strGroup & ",group" )
WScript.Echo "  Administrators group members:"
For Each objMember In objGroup.Members
  WScript.Echo "    " & objMember.Name
Next
 
A la place du wscript.echo tu peux renvoyer vers un fichier ou bien une DB.

Merci beaucoup !
Je vais essayer ça

Ca m'ouvre un popup qui me dit que le nom d'utilisateur est introuvable.
(ligne 6 carac 1)
 
J'ai utilisé :
 
 
Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName  
strGroup = "Administrateurs"
strUser = "MonUser sur l'Ad"
Set objGroup = GetObject("WinNT://" & strComputer & "/" & strGroup & ",group" )
Set objUser = GetObject("WinNT://" & strComputer & "/" & strUser & ",user" )
objGroup.Add(objUser.ADsPath)

A tout hasard, test avec le groupname 'administrators'. Si jamais ton image de départ est en anglais ton problème viendra de là.
 
Sinon, modifie le script pour qu'il te parcour l'ensemble des membres du groupe admin et de fasse un msgbox pour chaque occurence, histoire de vériier si déjà il arrive à faire ca...

j'avais essayé administrators, et là j'ai bien "groupe non trouvé".
 
Pour ta 2e soluce, n'y connaissant rien et n'y comprenant rien aux languages, je suis coincé, je ne sais pas faire.

Ca devrait donner ca, mais je ne l'ai pas testé et je me suis probablement gourré sur la partie for each.
 
Set wshNetwork = WScript.CreateObject( "WScript.Network" )  
strComputer = wshNetwork.ComputerName  
strGroup = "Administrateurs"  
 
' strUser = "MonUser sur l'Ad"  - Commenté
 
Set objGroup = GetObject("WinNT://" & strComputer & "/" & strGroup & ",group" )  
 
for each objuser in objgroup do
  msgbox objgroup.adsath
  objgroup.movenext
loop
' objGroup.Add(objUser.ADsPath)  - commenté

 
Effectivement
 
 
 
Ligne 6
caract 30
= Fin d'instruction attendue (pour la ligne "for each objuser in objgroup do" ).

Okay.
 
Est-que tu peux remplacer dans le script de départ (pas le mien donc) le username et me dire si cela fonctionne avec 'administrateur' ou le nom d'admin local que tu aurais mis par GPO ?

"Le nom de compte spécifié est déjà membre...".
 
Ok, donc le script tape en local et pas dans l'annuaire de l'AD ?

exactement.

Bon, par GPO ce n'est pas faisable.  
 
Il faut donc scripter, mais tu souhaites ajouter un compte du domain. Ton soucis est dans le script. Je le modifie, le test et te le post.
 
A bientôt !

Merci beaucoup !

Voilà le bébé et ça marche :
 
Dim DomainName
Dim UserAccount
Set net = WScript.CreateObject("WScript.Network" )
local = net.ComputerName
DomainName = "DomainName"
UserAccount = "userAccount"
 
set group = GetObject("WinNT://"& local &"/Administrateurs" )
 
on error resume next
group.Add "WinNT://"& DomainName &"/"& UserAccount &""
CheckError
 
sub CheckError
 if not err.number=0 then
 set ole = CreateObject("ole.err" )
 MsgBox ole.oleError(err.Number), vbCritical
 err.clear
Else
 MsgBox "Done."
end if
End Sub

oups, j'ai oublié : si tu ne veux pas de messages qui te disent Done, met un ' devant les lignes msgbox.

Parfait !
 
Merci à tous...

(note : que j'aime ton dernier smiley... héhé)