Problème de disparition programmée en AS3

Marsh Posté le 29-11-2012 à 14:44:14

Bonjour à tous !

Je réalise un petit jeu en flash pour un projet de ma fac', j'm'en sors pas trop trop mal (tout en restant dans le très basique, on n'est pas dans une formation très technique) sauf pour un petit truc que je n'arrive pas à régler

Je vous explique, j'ai une cible qui bouge sur l'écran, et j'ai une ligne qui suit ce movie clip et qui trace donc le chemin qu'il a parcouru.

Le problème c'est que si on ne clique pas sur la cible pendant un moment (ce qui réinitialise le chemin) bah l'écran devient surchargé très rapidement et fait même lagger mon PC.

J'aimerais donc faire en sorte que la trajectoire suive bien mon movie clip mais qu'elle disparaisse progressivement 3 secondes après son apparition afin qu'il n'y ait jamais trop de bordel à l'écran.

J'ai réussi à faire disparaitre la trajectoire avec un timer, mais le problème c'est que ça fait disparaître TOUTE la trajectoire et pas juste ce qui est apparu 3 secondes avant

En gros il me faudrait un truc du genre addChildFor(ligne, 3 secondes) mais à la dernière nouvelle ça n'a pas l'air d'exister

Vous auriez une idée par hasard?

Merci d'avance ! :jap:

---------------
Fuerte : https://www.youtube.com/watch?v=_8e2reyfvuc

Reply

Marsh Posté le 29-11-2012 à 14:44:14

Reply

Marsh Posté le 30-11-2012 à 16:16:13

Une methodologie simple :

A chaque frame, on enregistre les coordonnées du curseur.
On dessine un trait correspondant à la liaison des 50 dernières coordonnées enregistrées

Code :

var listePoint:Array = new Array();
var conteneurTrait:Shape = new Shape();
var couleurTrait:uint = 0xFF0000;
var nombreMaxPoints:int = 40;
        
 
addChild(conteneurTrait);
this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
 
function enterFrameHandler(e:Event):void
{
    var pointSurvol:Point = new Point(conteneurTrait.mouseX, conteneurTrait.mouseY); // Coordonnée en cours de survol
    listePoint.push(pointSurvol); // On l'ajoute en fin de notre tableau
    
    // On supprime les plus vieilles coordonnées :
    while (listePoint.length > nombreMaxPoints)
    {
        listePoint.shift();
    }
    drawPath();
}
        
function drawPath():void
{
    // On efface le trait actuel :
    conteneurTrait.graphics.clear();
            
    conteneurTrait.graphics.lineStyle(3,couleurTrait); // On déclare le style du trait
    conteneurTrait.graphics.moveTo(listePoint[0].x, listePoint[0].y); // On défini le point de départ (1er de la liste)
            
    // Pour chaque point (à partir du 2eme), on dessine le tronçon de trait
    for (var i:int = 1; i < listePoint.length; i++) 
    {
        conteneurTrait.graphics.lineTo(listePoint[i].x, listePoint[i].y);
    }
            
    conteneurTrait.graphics.endFill();
}

Ça marche assez bien si le taux de FPS est elevé.
Si il est faible et que tu ne peux pas l’élever, utilise un Timer plutôt qu'un Event.ENTER_FRAME !

Message édité par abais le 30-11-2012 à 16:40:23

---------------
Le membre ci-contre n'est pas responsable du message ci-dessus.

Reply

Marsh Posté le 30-11-2012 à 16:40:12

Idem avec une atténuation du trait (pas de transparence, c'est un mélange avec du blanc, plus qu'à mettre ton layer en mode produit !)
Je me prend un peu la tête avec le R/V/B :pt1cable: , pas le temps de faire plus simple

Code :

var listePoint:Array = new Array();
var conteneurTrait:Shape = new Shape();
 
var couleurTrait_R:uint = 0xFF;
var couleurTrait_V:uint = 0x00;
var couleurTrait_B:uint = 0x00;
 
var nombreMaxPoints:int = 40;
        
 
addChild(conteneurTrait);
this.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
 
function enterFrameHandler(e:Event):void
{
    var pointSurvol:Point = new Point(conteneurTrait.mouseX, conteneurTrait.mouseY); // Coordonnée en cours de survol
    listePoint.push(pointSurvol); // On l'ajoute en fin de notre tableau
    
    // On supprime les plus vieilles coordonnées :
    while (listePoint.length > nombreMaxPoints)
    {
        listePoint.shift();
    }
    drawPath();
}
        
function drawPath():void
{
    // On efface le trait actuel :
    conteneurTrait.graphics.clear();
    
    //conteneurTrait.graphics.lineStyle(3); // On déclare le style du trait
    conteneurTrait.graphics.moveTo(listePoint[0].x, listePoint[0].y); // On défini le point de départ (1er de la liste)
    
    // Pour chaque point (à partir du 2eme), on dessine le tronçon de trait
    for (var i:int = 1; i < listePoint.length; i++) 
    {
        var parcour:Number = i / listePoint.length;
        
        var r:String = '00'+(0xFF - (0xFF - couleurTrait_R) * parcour).toString(16);
        var v:String = '00'+(0xFF - (0xFF - couleurTrait_V) * parcour).toString(16);
        var b:String = '00'+(0xFF - (0xFF - couleurTrait_B) * parcour).toString(16);
        
        var couleur:uint = uint("0x"+r.substr(-2)+v.substr(-2)+b.substr(-2));
        conteneurTrait.graphics.lineStyle(3,couleur);
        conteneurTrait.graphics.lineTo(listePoint[i].x, listePoint[i].y);
    }
    
    conteneurTrait.graphics.endFill();
}

Message édité par abais le 30-11-2012 à 16:43:13

---------------
Le membre ci-contre n'est pas responsable du message ci-dessus.

Reply

Problème de disparition programmée en AS3

Sujets relatifs:

Leave a Replay