Deployer une imprimante sur le réseau

Marsh Posté le 03-05-2007 à 16:23:24

Bonjour,
Je viens d'installer une imprimante réseau sur un des PC de mon parc en suivant la procédure jointe. Celle-ci est accessible depuis mon serveur (Win2003) et je l'ai partagée sur le réseau.

Je voudrais savoir comment faire pour l'installer automatiquement sur tous les postes du réseaux (une vingtaine) sans devoir passer sur chaque machine ? Puis-je utiliser un script pour faire ca ?

Par avance merci de vos conseils.
A bientôt !

Reply

Marsh Posté le 03-05-2007 à 16:23:24

Reply

Marsh Posté le 06-05-2007 à 13:18:29

si le fameux PC sert de serveur d'impression tu n'aura pas besoin d'installer sur chaque poste.

Message cité 1 fois

Reply

Marsh Posté le 07-05-2007 à 16:28:10

wrksx a écrit :

si le fameux PC sert de serveur d'impression tu n'aura pas besoin d'installer sur chaque poste.

ben si faudrait quand meme faire un clic droit dessus "se connecter" donc aller la chercher sur le rezo...
sinon faire une GPO ( a condition d'etre en domaine AD)

Reply

Marsh Posté le 07-05-2007 à 17:26:18

Via un script de login que tu places en GPO tu peux ajouter une imprimante (ou plusieurs) et même par exemple en fonction du nom du PC, de l'utilisateur, ... choisir l'imprimante par défaut.

On Error Resume Next

Const E_ADS_PROPERTY_NOT_FOUND = &h8000500D
BS = Chr(92) ' Backslash
DBS = BS & BS ' Double Backslash

Set wshNetwork = WScript.CreateObject("WScript.Network" )
Set wshShell = WScript.CreateObject("WScript.Shell" )
Set wshSysEnv = wshShell.Environment("SYSTEM" )
sUser = LCase(wshShell.ExpandEnvironmentStrings("%USERNAME%" ))
sComputer = LCase(wshShell.ExpandEnvironmentStrings("%COMPUTERNAME%" ))
sServer = "nomduserveur"

' The pairs are "printers" and "default printer for computers"
aryPrinters = Array(Array(DBS & sServer & BS & "comptabilite_hp_laserjet_color_4600n", "pc001;pc002" ), _
Array(DBS & sServer & BS & "comptabilite_hp_laserjet_2420", "pc004" ), _
Array(DBS & sServer & BS & "couloir_hp_laserjet_4050n", "" ), _
Array(DBS & sServer & BS & "HPlaserjet 4250", "pc003;pc005;pc006;pc007;pc008" ), _
Array(DBS & sServer & BS & "couloir_hp_laserjet_5si", "" ), _
Array(DBS & sServer & BS & "couloir_photocopieuse_sharp", "" ), _
Array(DBS & sServer & BS & "couloir_hp_business_inkjet_2800_a3", "" ), _
Array(DBS & "autremachine" & BS & "valeur_hp_980cxi", "pc009;pc010" ))

' Disconnect all printers
Sub DisconnectPrinters()
Set colPrinters = wshNetwork.EnumPrinterConnections
For i = 0 To colPrinters.Count - 1 Step 2
wshNetwork.RemovePrinterConnection colPrinters(i)
Next
End Sub

' Map printer
Sub MapPrinter(sPrinter)
wshNetwork.AddWindowsPrinterConnection sPrinter
End Sub

' Set Default Printer
Sub SetDefaultPrinter(sPrinter)
wshNetwork.SetDefaultPrinter sPrinter
End Sub

DisconnectPrinters

' Connect printers
For i = LBound(aryPrinters) to UBound(aryPrinters)
aryAux = aryPrinters(i)
MapPrinter aryAux(0)
aryComputers = Split(aryAux(1), ";" )
For j = LBound(aryComputers) to UBound(aryComputers)
If sComputer = aryComputers(j) Then
SetDefaultPrinter(aryAux(0))
End If
Next
Next

' Delete objects
Set wshNetwork = Nothing
Set wshShell = Nothing
Set wshSysEnv = Nothing

Evidemment il faut l'adapter à tes besoins...

Message édité par Requin le 07-05-2007 à 17:27:45

Reply

Deployer une imprimante sur le réseau

Sujets relatifs:

Leave a Replay